Допуск к лабораторной работе №6

ORG 000

RET: WORD ?

NOP ;Ячейка для отладочной точки останова

BR INT ;Переход к обработке прерывания

ORG 120

INT: WORD ?

MOV SAVEA ;Сохранение аккумулятора и регистра С

ROL

MOV SAVEC

CHECK2: TSF 2 ;Опрос флага ВУ-2

BR CHECK3 ;Если сброшен, то перейти к опросу флага ВУ-3

BR READY2 ;Иначе перейти к работе с ВУ-2

CHECK3: TSF 3 ;Опрос флага ВУ-3

BR READY1 ;Если сброшен, то перейти к работе с ВУ-1

BR READY3 ;Иначе перейти к работе с ВУ-3

READY2: CLA

IN 2

MOV EXTVAL

JSR SF\_X ;Ввести значение с ВУ-2 и вычесть его из х

NOP ;Отладочная точка останова

CLF 2 ;Сброс флага ВУ-2

BR RSTOR ;Переход к восстановлению аккумулятора и С

READY3: CLA

ADD X

CLC

ROL

ADD X

CLC

ROL

MOV SIXX ;Увеличить х в 6 раз и запомнить

CLA

SUB SIXX ;Взять х увеличенный в 6 раз со знаком минус

SUB SVN ;Вычесть 7

OUT 3 ;Вывести результат на ВУ-3

NOP ;Отладочная точка останова

CLF 3 ;Сброс флага ВУ-3

BR RSTOR ;Переход к восстановлению аккумулятора и С

READY1: CLF 1 ;Сброс флага ВУ-1

RSTOR: CLA

ADD SAVEC ;Восстановть регистр С

ROR

CLA

CMA

AND SAVEA ;Восстановить аккумулятор не затрагивая С

EI ;Разрешить прерывания

BR (RET) ;Вернуться в основную программу

ORG 008

X: WORD 0000 ;Ячейка для записи переменной х

ORG 010

TWO: WORD 0002

SAVEA: WORD 0000

SAVEC: WORD 0000

EXTVAL: WORD 0000 ;Значение, считываемое с ВУ2

SIXX: WORD 0000 ;Произведение х и 6

SVN: WORD 0007

AHB: WORD 0014 ;Максимальное значение х

ALB: WORD 0015 ;Модуль минимального значения х

ORG 020 ;Основная программа

BEGIN: EI ;Разрешить прерывния

CLA

LOOP: JSR EDIT\_X ;Перейти к подпрограмме изменения х

BR LOOP

;Подпрограмма для уменьшения х на 2

EDIT\_X: WORD ? ;Адрес возврата

CLA

ADD X ;Загружаем х в аккумулятор

DI ;Запрещаем прерывания на время изменения х

SUB TWO ;Уменьшаем х на два

JSR CHECKX ;Проверка на соответствие ОДЗ и запись х в память

EI ;Разрешаем прерывания

BR (EDIT\_X) ;Возвращаемся в основную программу

;Подпрограмма для вычитания из х значения с ВУ-2

SF\_X: WORD ? ;Адрес возврата

CLA

ADD X

SUB EXTVAL ;Вычитаем из х прочитанное с ВУ-2 значение

JSR CHECKX ;Проверка на соответствие ОДЗ и запись х в память

BR (SF\_X) ;Возвращаемся в основную программу

;Подпрограмма для проверки и записи х в память

CHECKX: WORD ? ;Адрес возврата

SUB AHB

BPL CORR ;Если х > верхней границы

ADD AHB

ADD ALB

BMI CORR ;Или x < нижней границы то приравнять х верхней границе

SUB ALB

BR MOVING ;В противном случае сразу записать х в память

CORR: CLA

ADD AHB

MOVING: MOV X

BR (CHECKX)

Методика проверки программного комплекса

1. Загрузить комплекс программ в память базовой ЭВМ.

2. Изменить значение точки останова по адресу 12E16 на HLT

3. Запустить основную программу в автоматическом режиме с адреса 2016

4. Установить "Готовность ВУ-3".

5. Дождаться останова

6. Записать содержимое регистра данных ВУ-3 в момент останова программы

7. Изменить значение точки останова по адресу 13E16 на HLT

8. Запустить основную программу в автоматическом режиме с адреса 2016

9. Установить "Готовность ВУ-2".

10. Дождаться останова

11. Записать содержимое аккумулятора в момент останова программы